#include "colors.inc"
#include "textures.inc"
#include "stones.inc"
#include "alien.inc"

camera {
        location <0, 20, -500>
        right <640/480, 0, 0>
        look_at <0, 150, 0>
}

light_source { <1000, 500, -1200> color White }

plane { <0, 1, 0>, -10
        pigment { color rgb <.2, .3, .4> }
        finish { ambient .3 }
}

plane { <0, 1, 0>, 0
        pigment { color rgbf <.2, .3, .4, .2> }
        finish { 
                diffuse .6
                ambient .2 
                reflection .8
                specular .4
        }
        normal { bumps .4 scale 22 }
        translate <14, 0, 0>
}

disc { <0, 0, 0>, <0, 0, 1>, 1
        pigment {
                onion
                color_map {
                        [0 color rgbf <1.25, 1.25, 1.25, 0>]
                        [1 color rgbf <1, 1, 1, 1>]
                }
        }
        finish { diffuse 0 ambient 1 }
        scale 100
        translate <5, 275, -10>
}


union {
        height_field {
                gif "alien2.ghf"
                smooth
                water_level .05
                translate <-.5, -.2, -.5>
                scale <300, 80, 300>
        }
        height_field {
                gif "alien3.ghf"
                water_level .05
                translate <-.5, 0, -.5>
                rotate <0, 170, 0>
                scale <200, 80, 200>
                translate <0, 35, 0>
        }
        height_field {
                gif "alien1.ghf"
                water_level .2
                translate <-.5, 0, -.5>
                rotate <0, 0, 0>
                scale <100, 250, 100>
                translate <0, 50, 0>
        }
        texture { Stone8 }
}

object { Spiral }

sphere { <0, 0, 0>, 1
        texture { 
           pigment {
              bozo
              turbulence 0.5
              octaves 3   
              lambda 6     
              color_map {
                [0.0 0.1 color Clear color Clear]
                [0.8 color rgb <1, .4, .8>]
                [1.0 color rgb <.8, .2, .6>]
              }
           }
           finish { ambient 1 diffuse 0 }
           scale 1/6   
           rotate <160, 0, 0>
        }
        scale <50000, 5000, 50000>
}

sphere { <0, 0, 0>, 1
        pigment { color NewMidnightBlue }
        finish { diffuse 0 ambient 1 }
        scale <100000, 10000, 100000>
}

sphere { <0, 0, 0>, 1
        pigment {
                image_map {
                        gif "neptune.gif"
                        interpolate 4
                        once
                }
                translate <-.5, -.5, 0>
                scale 2
        }
        finish { diffuse 0 ambient 1 }
        scale 1200
        translate <0, 0, 20000>
        rotate <-23, 0, 0>
        rotate <0, 27, 0>
}