#include "colors.inc"
#include "textures.inc"
#include "lthing.inc"
#include "lattice.inc"
#include "star.inc"

light_source { <-18,20,-20>  color rgb<.95,.95,.95> }
light_source { <3.4,1.8,2.2>
              color red 1 blue .2
              spotlight
              point_at <4.9,1.82,4>
              radius 20
              falloff 53
              tightness 8
} 
light_source { <3.4,1.8,2.2>
              color red .35 blue .8 green .2
              spotlight
              point_at <4.9,1.82,4>
              radius 4
              falloff 14
              tightness 10
} 

camera {
  location <4.9,4,-2.2>
  look_at <5,1,5>
}

//------- Red Swirl       this is from stones.inc
#declare Grnt28 =
texture {
pigment
 {marble
  turbulence 0.7
  color_map
   {[0.000, 0.155   color rgbf <0.686, 0.235, 0.282, 0.000>
                    color rgbf <0.686, 0.235, 0.282, 0.000>]
    [0.155, 0.328   color rgbf <0.686, 0.235, 0.282, 0.000>
                    color rgbf <0.494, 0.243, 0.294, 0.000>]
    [0.328, 0.474   color rgbf <0.494, 0.243, 0.294, 0.000>
                    color rgbf <0.769, 0.329, 0.373, 0.000>]
    [0.474, 0.647   color rgbf <0.769, 0.329, 0.373, 0.000>
                    color rgbf <0.769, 0.329, 0.373, 0.000>]
    [0.647, 0.810   color rgbf <0.769, 0.329, 0.373, 0.000>
                    color rgbf <0.686, 0.235, 0.282, 0.000>]
    [0.810, 0.922   color rgbf <0.686, 0.235, 0.282, 0.000>
                    color rgbf <0.792, 0.388, 0.427, 0.000>]
    [0.922, 1.001   color rgbf <0.792, 0.388, 0.427, 0.000>
                    color rgbf <0.686, 0.235, 0.282, 0.000>]
   }
 }
 finish {
  crand 0.03
 }
 }

#declare binary = texture {
  pigment {  
    image_map {
      gif "binary.gif"
    } 
  }
  scale 2
  translate <0,-1,0>
}
  
#declare mandmap = 
  texture {   
    material_map {
      gif "mmap1.gif"
      texture {pigment {color Green}}
      texture {pigment {color Clear}}    //mset
      texture {pigment {color blue 1  }}
      texture {pigment {color blue 1 }}
      texture {pigment {color blue 1 }}
      texture {pigment {color blue 1 }}
      texture {pigment {color blue 1 }}
      texture {pigment {color blue 1 }}
      texture {binary}
      texture {pigment {
        image_map {
            gif "fract.gif"            
            interpolate 2
          } 
          } 
        scale 10
      }
      texture {binary}
      texture {pigment {color blue .5  }
        finish {ambient .4 brilliance 5 }
      }
      texture {pigment {color blue .6 }
        finish {ambient .5 brilliance 10 }
      }
      texture {pigment {color blue .7  }
        finish {ambient .5 brilliance 20 }
      }
      texture {pigment {color blue .9  }
        finish {ambient .8 brilliance 30 }
      }
      texture {pigment {color blue 1  }
        finish {ambient .9 brilliance 40 }
      }
    }
  scale 10
  rotate <90,0,0>   
}

plane { <0,1,0>, 0
  texture { mandmap }
  no_shadow
  clipped_by { plane { z, 12 }  }
  clipped_by { plane { x, 12 }  }
}

height_field {
  gif "cpuhf03.ghf"
  water_level .1
  scale <9,2.7,9>
  translate <-1.5,-.2,5>
  texture { binary  
    scale 12
    rotate <60,0,0>
  }
  texture { 
    pigment {
      gradient y
      color_map {
        [  0 color Clear ]
        [ .1 color Clear ]
        [  1 color Red   ]
      }
    }
  scale <9,2.7,9>
  translate <-1.5,-.2,5>  
  } 
}

union {
  object { LineThing }
  object { LineThing 
    rotate <0,0,-90>
    translate <1,1,0>
  }
  object { LineThing 
    rotate <0,0,-180>
    translate <2,0,0>
  }
  object { LineThing 
    rotate <0,0,-270>
    translate <1,-1,0>
  }
  texture {
    pigment {color White}
  }
  scale 13
  rotate <0,0,180>
  rotate <0,70,0>
  translate <13,5,-3.7>
}
  
sphere { <14.8,6,20>, 8 
  texture {
    pigment { color Gray40
    }
  }
}


object { Lattice 
  texture { pigment { color Gray} }
    no_shadow
  rotate <0,0,-10>
  rotate <-15,0,0>
}

object { star
  texture {Grnt28 }
  rotate <0,12,0>
  scale .6
  translate <2.7,1.6,2.3>
}