/***************************************************************************/
//		smiley.pov
//		by Hero Ngauv
/***************************************************************************/

#include "colors.inc"
#include "textures.inc"

camera{
  location <0,0.5,-12>
  direction <0,0,7>
  up <0,1,0>
  right <4/3,0,0>
  look_at <0,0.9,0>
}
/***************************************************************************/
light_source{ <-3.5,2.5,-5> color Gray75 }	//for the eyes
light_source{ <3.5,2.5,-5> color Gray75 }

#declare sw = 12			//smile width
#declare sb = color Gray50		//smile brightness

light_source{ <sw,-15,-4> color sb }	//for the mouth;  as the lights
light_source{ <sw*2/3,-15,-4> color sb }	//are spread out wider, the
light_source{ <sw*1/3,-15,-4> color sb }	//phong highlights will curve
light_source{ <0,-15,-4> color sb }		//around the surface of the
light_source{ <-sw*1/3,-15,-4> color sb }	//sphere, giving the
light_source{ <-sw*2/3,-15,-4> color sb }	//appearance of a smile
light_source{ <-sw,-15,-4> color sb }
/***************************************************************************/
sphere{ <0,0.9,0>, 0.75		//the smiley
  texture{
    pigment{
      color rgb <1,1,0>
    }
    finish{
      Metal
      reflection 0
      diffuse 0.3	//this is so the sphere isn't too bright with
    }			//all the lights shining on it
  }
}