EMAIL: zerozerozerozero@wyan.org
NAME: Michael Chelmecki
TOPIC: SPEED
COPYRIGHT: I SUBMIT TO THE STANDARD RAYTRACING COMPETITION COPYRIGHT.
TITLE: Speed of Life
COUNTRY:United States
WEBPAGE: Private
RENDERER USED: POVray 3.6
TOOLS USED: IrfanView - convert to JPEG, gamma correct
RENDER TIME: 1 hr, 17 min, 18 sec
HARDWARE USED: AMD K6

IMAGE DESCRIPTION:
Three different time keeping devices from three different centuries depict
sharply contrasting attitudes and ideas about how fast we ought to be
moving and why.  The 19th Century cuckoo clock, built slowly and carefully
by an artisan, has no second hand.  It recalls an era, already starting to
pass away at the time of the clock’s creation, in which people and events
move at a rate conducive to savoring the passage of well used time as a
gourmet might savor a fine meal.  The airplane clock, a design icon of the
mid 20th Century, shows that attitudes about speed and time have changed
dramatically.  Things move fast.  Smooth, shiny and streamlined, it evokes
a sense of adventure and optimism with regard to modernism’s headfirst
plunge into the future.  To represent the dominant perspective on speed and
time at the start of the 21st Century, I chose the cesium clock.  It has no
aesthetic elements whatsoever.  It is a purely functional device designed for
regulation, standardization and control.  We move faster than ever before,
but the sense of adventure is gone.  Time, like everything else, is an
economic commodity.  No speed is fast enough as we rush to meet endlessly
increasing demands for greater productivity, lest we cease to be "competitive",
and in so doing, cease to be.

DESCRIPTION OF HOW THIS IMAGE WAS CREATED:
I've always felt that the best description of how an image is created
is the source code, which is listed below. Two textures, "Soft_Silver"
and "Aluminum" from the standard POVray include file "textures.inc"
were used.  All of the font files used for clock numbers and various
printed items are named in the source code.  The "process", such as
it is, consists entirely of playing around with CSG until I get something
that I like.  It's a hobby, like building ships in bottles (or cuckoo clocks?).


POV source code:

global_settings { assumed_gamma 2.2 }
#include "textures.inc" 
sky_sphere { pigment {rgb<1,1,1>}}

camera { location <1.5,2.0, -10> direction <0, 0, 3.25 > up <0, 1, 0>
right  x*image_width/image_height look_at <1.8, .6 , 1> }

light_source { <8,14, -15> colour .25 } light_source { <-8,14, -15> colour .25 } 
light_source { <12,14, -15> colour .25 } light_source { <-12,14, -15> colour .25 } 

#declare Crys = material{texture{ pigment{ rgbft<1,1,1,.5,.5> }
        finish{ambient .25 diffuse .5 reflection .1 phong .8 phong_size 30} rotate<90,0,0>} interior{ior 1.1} }  
#declare GLt = material{texture{ pigment{ rgbft<1,3,1,.5,.5> }
        finish{ambient .05 diffuse .5 reflection .1 phong .8 phong_size 30} rotate<90,0,0>} interior{ior 1.0} } 
#declare YLt = material{texture{ pigment{ rgbft<3,3,1,.5,.5> }
        finish{ambient .28 diffuse .5 reflection .3 phong .8 phong_size 30} rotate<90,0,0>} interior{ior 1.0} } 
#declare RLt = material{texture{ pigment{ rgbft<3,1,1,.5,.5> }
        finish{ambient .28 diffuse .5 reflection .3 phong .8 phong_size 30} rotate<90,0,0>} interior{ior 1.1} } 
#declare DTRC = material{texture{ pigment{ rgbft<1,1,1,.5,.5> }
        finish{ambient 0 diffuse .5 reflection .1 phong .2 phong_size 10} } interior{ior 1.05} }
#declare MGld = texture{ pigment{ color rgb<.8,.75,.3> }
        finish{ambient .2 diffuse .7 reflection .3 phong .9 phong_size 20 metallic} rotate<90,0,0>} 
#declare MChr = texture{ pigment{ color rgb<.8,.8,.83> }
        finish{ambient .1 diffuse .4 reflection .5 phong .95 phong_size 40 metallic} rotate<90,0,0>} 
#declare MSil = texture{ pigment{ color rgb<.79,.80,.81> }
        finish{ambient .2 diffuse .4 reflection .4 phong .95 phong_size 20 metallic} rotate<90,0,0>} 
#declare GreyMet = texture{ pigment{ color rgb<.77,.82,.83> }
        finish{ambient .6 diffuse .25 reflection .15 phong .95 phong_size 20 metallic} rotate<90,0,0>} 
#declare TanMet = texture{ pigment{ color rgb<.96,.96,.87> }
        finish{ambient .6 diffuse .35 reflection .05 phong .5 phong_size 20 metallic} rotate<90,0,0>} 
#declare MDMt = texture{ pigment{ color rgb<.35,.32,.15> }
        finish{ambient .2 diffuse .8 reflection .3 phong 1 phong_size 30 metallic} rotate<90,0,0>} 
#declare DRB = texture{ pigment{ color rgb<.05,.05,.08> }
        finish{ambient 0 diffuse 0 reflection .1 phong .1 phong_size 5 }} 
#declare MBlu =texture{ pigment{ color rgb<.1,.3,1> }  finish{ambient 1.5 diffuse .4 reflection .2 phong 1 phong_size 15 }}  
#declare RGrn =texture{ pigment{ color rgb<.2,.3,.2> }  finish{ambient .8 diffuse .4 reflection .02 phong .5 phong_size 15 }}  
#declare BWht =texture{ pigment{ color rgb<1,1,1> }  finish{ambient .6 diffuse .5 reflection .02 phong .8 phong_size 45 }}  
#declare BWhtB =texture{ pigment{ color rgb<1,1,1> }  finish{ambient .7 diffuse .6 reflection .02 phong .8 phong_size 45 }}  
#declare SYlo =texture{ pigment{ color rgb<.9,.8,.2> }  finish{ambient .4 diffuse .8 reflection .02 phong .5 phong_size 15 }}
#declare SYlo2 =texture{ pigment{ color rgb<.9,.8,.2> }  finish{ambient 1 diffuse .8 reflection .02 phong .5 phong_size 15 }}  
#declare MyDWood = texture{ pigment{ color rgb<.6,.50,.35> }  finish{ambient .3 diffuse .7  phong .4 phong_size 10 }}    
#declare CCWood = texture{ pigment{ bozo  color_map {[0 rgb<.7,.55,.4>] [.5 rgb<.55,.4,.15>] [1 rgb<.60,.45,.25>]}
        turbulence 1.3 omega 0.8}  finish{ambient .3 diffuse .7  phong .4 phong_size 10 } scale<.6,.03,.6>} 
#declare PBrd = texture{ pigment{ bozo  color_map {[0 rgb<.85,.82,.72>] [.5 rgb<.75,.72,.58>] [1 rgb<.80,.80,.65>]}
        turbulence 2.3 omega 3.2}  finish{ambient .5 diffuse .5  phong .4 phong_size 10 } scale<.08,.08,.08>}                                                                           
#declare CCBlu = texture{ pigment{ bozo  color_map {[0 rgb<.5,.65,.8>] [.5 rgb<.55,.7,.85>] [1 rgb<.60,.75,.90>]}
        turbulence 1.3 omega 0.8}  finish{ambient .3 diffuse .7  phong .4 phong_size 10 } scale<.6,.03,.6>} 
#declare CBBox = texture{ pigment{ color rgb<.7,.65,.55> }  finish{ambient .4 diffuse .8  phong .1 phong_size 15 }}  
 
 
//Cesium Clock 
//======================================================================================================
#declare REBx = union{cylinder{<.1,-.1,0>,<.1,-.1,1>,.1}  cylinder{<.1,-.9,0>,<.1,-.9,1>,.1} 
 cylinder{<.9,-.1,0>,<.9,-.1,1>,.1}  cylinder{<.9,-.9,0>,<.9,-.9,1>,.1} 
 box {<0,-.1,0>,<1,-.9,1>}  box {<.1,0,0>,<.9,-1,1>} }                     
 
 difference{box{<0,0,0>,<3.6,-.6,4>}
 #declare SGX=0; #while (SGX<4)  #declare SGZ=0; #while (SGZ<3)  #declare CSOS=0; #while(CSOS<.9)
 box{<.2,-.5,.2>,<.21,1,1.2> translate<CSOS+SGX,0,SGZ>} 
 #declare CSOS=CSOS+.04; #end #declare SGZ=SGZ+1.2; #end #declare SGX=SGX+1.15; #end 
 #declare BXP=0; #while(BXP<5) #declare BYP=0; #while(BYP<3)
 object{REBx scale<.11,.11,1> translate<2.0+.13*BXP,-.12-.13*BYP,-.95>}
 #declare BYP=BYP+1; #end  #declare BXP=BXP+1; #end
 box{<.35,-.45,-1>,<1.05,-.47,.2>}
 texture{GreyMet}} 

object{REBx scale<.02,.1,1> translate<.58,-.39,-.03> texture{Aluminum}}

torus{.035,.006 rotate<90,0,0> translate<1.65,-.15,0> texture{Aluminum} }
sphere{<0,0,0>,.03 scale <1,1,.5>   translate<1.65,-.15,0>material{GLt} }  

torus{.035,.006 rotate<90,0,0> translate<1.65,-.28,0> texture{Aluminum} }
sphere{<0,0,0>,.03 scale <1,1,.5>   translate<1.65,-.28,0>material{YLt} }  

torus{.035,.006 rotate<90,0,0> translate<1.65,-.41,0> texture{Aluminum} }
sphere{<0,0,0>,.03 scale <1,1,.5>   translate<1.65,-.41,0>material{RLt} }  

#declare BXP=0; #while(BXP<5) #declare BYP=0; #while(BYP<3)
object{REBx scale<.09,.090,1> translate<2.02+.13*BXP,-.122-.13*BYP,.02> texture{BWht}}
#declare BYP=BYP+1; #end  #declare BXP=BXP+1; #end

text { ttf "arial.ttf" "+" 1, 0 scale <.08,.08,.04> translate<2.04,-.197,.019> } 
text { ttf "arial.ttf" "7" 1, 0 scale <.08,.07,.04> translate<2.045+.13*1,-.197,.019> }
text { ttf "arial.ttf" "8" 1, 0 scale <.08,.07,.04> translate<2.045+.13*2,-.197,.019> } 
text { ttf "arial.ttf" "9" 1, 0 scale <.08,.07,.04> translate<2.045+.13*3,-.197,.019> }
text { ttf "arial.ttf" "<=" 1, 0 scale <.05,.07,.04> translate<2.03+.13*4,-.197,.019> } 
text { ttf "arial.ttf" "-" 1, 0 scale <.08,.08,.04> translate<2.05,-.197-.13*1,.019> } 
text { ttf "arial.ttf" "4" 1, 0 scale <.08,.07,.04> translate<2.045+.13*1,-.197-.13*1,.019> }
text { ttf "arial.ttf" "5" 1, 0 scale <.08,.07,.04> translate<2.045+.13*2,-.197-.13*1,.019> } 
text { ttf "arial.ttf" "6" 1, 0 scale <.08,.07,.04> translate<2.045+.13*3,-.197-.13*1,.019> }
text { ttf "arial.ttf" "CE" 1, 0 scale <.05,.07,.04> translate<2.03+.13*4,-.197-.13*1,.019> }
text { ttf "arial.ttf" "0" 1, 0 scale <.08,.08,.04> translate<2.04,-.199-.13*2,.019> } 
text { ttf "arial.ttf" "1" 1, 0 scale <.08,.07,.04> translate<2.045+.13*1,-.197-.13*2,.019> }
text { ttf "arial.ttf" "2" 1, 0 scale <.08,.07,.04> translate<2.045+.13*2,-.197-.13*2,.019> } 
text { ttf "arial.ttf" "3" 1, 0 scale <.08,.07,.04> translate<2.045+.13*3,-.197-.13*2,.019> }
text { ttf "arial.ttf" "ESC" 1, 0 scale <.03,.07,.04> translate<2.03+.13*4,-.197-.13*2,.019> }  

#declare Coax1 = difference{sphere{<0,0,0>, .08 scale<1,1,.45>} box{<-1,.065,-1>,<1,1,1>} box{<-1,.065,-1>,<1,1,1> rotate<0,0,60>}
box{<-1,.065,-1>,<1,1,1> rotate<0,0,120>}box{<-1,.065,-1>,<1,1,1> rotate<0,0,180>}
box{<-1,.065,-1>,<1,1,1> rotate<0,0,240>}box{<-1,.065,-1>,<1,1,1> rotate<0,0,300>} 
box{<-1,-1,-1>,<1,1,-.03>}
 texture{MChr}}
 
#declare Coax = union{object {Coax1} #declare CTh=0; #while (CTh<9)
torus{.045,.007 rotate <90,0,0> translate<0,0,-.03-.013*CTh> texture{MChr}}
#declare CTh=CTh+1; #end 
difference{cylinder{<0,0,0>,<0,0,-.095>,.030 texture {BWht}} cylinder{<0,0,0>,<0,0,-.1>,.010 texture {MGld}} }
}   

object {Coax translate <3.34,-.41,0>}
object {Coax rotate <0,0,25> translate <2.84,-.41,0>}
object {Coax rotate <0,0,75> translate <3.09,-.41,0>}  

#declare FScr = difference{sphere{<0,0,0>,.04 scale<1,1,.1>} box{<-.008,-1,0>,<.008,1,-1>}texture{MChr}} 
object{FScr rotate <0,0,5> translate<1.8,-.03,-.055>}
object{FScr rotate <0,0,15> translate<1.8,-.54,-.055>}
object{FScr rotate <0,0,-20> translate<.05,-.03,-.055>}
object{FScr rotate <0,0,50> translate<.05,-.54,-.055>}
object{FScr rotate <0,0,25> translate<3.55,-.03,-.055>}
object{FScr rotate <0,0,60> translate<3.55,-.54,-.055>}

difference{
box{<-.2,.02,0>,<3.8,-.6,-.05>}  
object{REBx scale <.5,.5,1> translate<.1,-.035,-.95>} object{REBx scale <.85,.5,1> translate<.5,-.035,-.95>} 
object{REBx scale <.5,.5,1> translate<1.25,-.035,-.95>}  
object{REBx scale <.5,.5,1> translate<3.0,-.035,-.95>}object{REBx scale <.85,.5,1> translate<2.25,-.035,-.95>}
object{REBx scale <.5,.5,1> translate<1.85,-.035,-.95>} 
object{REBx scale<.2,.05,1> translate<-.3,-.15,-.5>}  object{REBx scale<.2,.05,1> translate<3.7,-.15,-.5>} 
object{REBx scale<.2,.05,1> translate<-.3,-.40,-.5>}  object{REBx scale<.2,.05,1> translate<3.7,-.40,-.5>} 
texture{Soft_Silver}}  
                     
torus{.27,.03 rotate<0,0,90> scale <1,1,.5> translate<-.05,-.3,0> texture{Soft_Silver}}
torus{.27,.03 rotate<0,0,90> scale <1,1,.5> translate<3.65,-.3,0> texture{Soft_Silver}}                          

text { ttf "lsansuni.ttf" "364:19:00:04" 1, 0 scale <.13,.13,.2> translate<.22,-.25,-.002> texture{MBlu}} 

box{<0,0,0>,<1,-1,1> scale <.94,.17,1> translate <.185,-.12,-.05> material {Crys}}  
box{<0,0,0>,<1,-1,1> scale <.94,.16,1> translate <.185,-.12,-.001> texture{DRB}}  

text { ttf "arial.ttf" "MHz" 1, 0 scale <.05,.05,.04> translate<.18,-.37,-.0025> }
text { ttf "arial.ttf" ".1" 1, 0 scale <.05,.05,.04> translate<.38,-.37,-.0025> }
text { ttf "arial.ttf" "1" 1, 0 scale <.05,.05,.04> translate<.58,-.37,-.0025> } 
text { ttf "arial.ttf" "5" 1, 0 scale <.05,.05,.04> translate<.78,-.37,-.0025> }
text { ttf "arial.ttf" "10" 1, 0 scale <.05,.05,.04> translate<.98,-.37,-.0025> } 
text { ttf "arial.ttf" "LOCK" 1, 0 scale <.05,.05,.04> translate<1.42,-.175,-.0025> } 
text { ttf "arial.ttf" "MINOR ALARM" 1, 0 scale <.05,.05,.04> translate<1.22,-.305,-.0025> }
text { ttf "arial.ttf" "MAJOR ALARM" 1, 0 scale <.05,.05,.04> translate<1.22,-.435,-.0025> }
text { ttf "arial.ttf" "1 PPS" 1, 0 scale <.05,.05,.04> translate<2.76,-.29,-.0025> }
text { ttf "arial.ttf" "SYNC" 1, 0 scale <.05,.05,.04> translate<3.01,-.29,-.0025> }
text { ttf "arial.ttf" "LINE" 1, 0 scale <.05,.05,.04> translate<3.28,-.29,-.0025> }
text { ttf "ocraext.ttf" "CESIUM TIME STANDARD" 1, 0 scale <.06,.08,.04> translate<2.71,-.185,-.0025> } 
text { ttf "dec097.ttf" "1" 1, 0 scale <.2,.2,.04> translate<1.20,-.24,-.0025> }  


// Rack
//======================================================================================================
box{<-2,-.7,-.3>,<5,-.72,4.5> texture {PBrd}}
box{<-2,-.71,-.32>,<5,-.95,4.5> texture {TanMet}}                       

difference{box{<3.7,-3,4.5>,<4.0,7,4.7>}box{<3.71,-3,4.51>,<3.99,7,4.69>} 
cylinder{<3.85,1.5,0>,<3.85,1.5,9>,.05} box{<3.83,1.6,3>,<3.87,2.0,9>} box{<3.83,1.4,3>,<3.87,1.0,9>} 
box{<3.83,1.4,3>,<3.87,1.0,9> translate<0,-1,0>}
texture {TanMet}} 
 
union{cylinder{<3.7,1.6,0>,<-2,1.6,0>,.15 scale <1,1,.3> translate <0,0,4.6>} 
box{<3.6,1.6,4.40>,<-3,1.44,4.7>} texture{TanMet}}
  
union{cylinder{<3.7,1.6,0>,<-2,1.6,0>,.15 scale <1,1,.3> translate <0,0,4.6>} 
box{<3.6,1.6,4.40>,<-3,1.44,4.7>} texture{TanMet} translate<-3.7,0,-4.6> rotate<0,180,0>  translate<3.7,0,4.6>
translate<0.,-.5,0>}
 
box{<-90,-90,50>,<90,90,50.2> texture{TanMet}}


// Cuckoo Clock 
//======================================================================================================
#declare OPR=0;
#declare RoOrn =  union{#while(OPR<360) difference{
difference{torus{.04,.02 }box{<.022,.2,0>,<-.2,-.2,-.2>} rotate<-90,0,0> scale <1,.8,1>translate<.04,0,0> rotate<0,0,OPR>} 
box {<-1,-1,-1>,<1,1,-.0195>} }
#declare OPR=OPR+360/8; #end
difference{sphere{<0,0,0>,.03 scale<1,1,.6>} box{<-1,-1,-1>,<1,1,-.016>}translate <0,0,-.01> }}

#declare Lf1 = union{ difference{sphere{<0,0,0>,.04} box{<-1,-1,-1>,<0,1,1>}scale<2,1,1>} 
 difference{sphere{<0,0,0>,.04} box{<1,-1,-1>,<0,1,1>} scale<5,1,1>} scale<.3,.5,.3> }
#declare Lf2 = difference{object{Lf1} sphere{<0,0,0>,.04 scale<2,.5,.20> translate<-.03,0,-.013>}scale<1,1,2>}  
#declare Lf3 = union{object {Lf2} sphere{<0,0,0>,.01 scale<5,.5,2> translate< .01,0,0>}}
#declare Lf = difference{object {Lf3}  box{<-1,-1,-1>,<1,1,-.0145>}} 

#declare CClock1 = union{ box{<-.55,1.5,-.30>,<.55,.31,.399>} box{<-.680,.321,-.470>,<.680,.05,.470>} 
cylinder{<0,.04,0>,<0,.322,0>,.02 translate<-.680,0,-.470>} cylinder{<0,.04,0>,<0,.322,0>,.02 translate< .680,0,-.470>}
cylinder{<0,.04,0>,<0,.322,0>,.02 translate<-.345,0,-.470>} cylinder{<0,.04,0>,<0,.322,0>,.02 translate< .345,0,-.470>}
cylinder{<0,.04,0>,<0,.322,0>,.02 translate<-.680,0, .470>} cylinder{<0,.04,0>,<0,.322,0>,.02 translate< .680,0, .470>}
object{RoOrn translate < 0,.2,-.457>} object{RoOrn translate < -.51,.2,-.46>}object{RoOrn translate < .51,.2,-.46>}

#declare RLO=-24; #while(RLO<=24)
object{Lf  translate  <-.18,0,0> rotate<0,0,RLO> translate  <0,.2,-.47>} 
object{Lf  translate  <-.18,0,0> rotate<0,0,RLO+180> translate  <0,.2,-.47>}
#declare RLO=RLO+12; #end
torus{.12,.015 rotate<90,0,0> translate  <0,.2,-.468>} 
intersection{torus{.24,.015 rotate<90,0,0> translate  <0,.2,-.468>} box{<-1,.3,-1>,<1,.1,1>}  }

  difference{box{<-.685*1.11,-.1,-.475*1.11>,<.685*1.11,.05,.475*1.11>}
  box{<-.6851,-.11,-.475>,<.685,.06,.475>}
  cylinder{<0,0,-2>,<0,0,2>,.1 scale <1.6,.8,1> rotate<0,0,-18> translate< -.48,-.11,0>}
  cylinder{<0,0,-2>,<0,0,2>,.1 scale <1.6,.8,1> rotate<0,0, 18> translate<  .48,-.11,0>}
  difference{cylinder{<0,0,-2>,<0,0,2>,.1} cylinder{<0,.1,-2.1>,<0,.1,2.1>,.095}scale <1.4,.8,1>rotate<0,0, 10> translate<  .17,-.095,0>}
  difference{cylinder{<0,0,-2>,<0,0,2>,.1} cylinder{<0,.1,-2.1>,<0,.1,2.1>,.095}scale <1.4,.8,1>rotate<0,0,-10> translate< -.17,-.095,0>}
  cylinder{<0,0,-2>,<0,0,2>,.1 scale <1.6,.8,1> rotate<0,0,-18> translate< -.17,-.11,0> rotate<0,90,0> scale<1,1,1.3>}
  cylinder{<0,0,-2>,<0,0,2>,.1 scale <1.6,.8,1> rotate<0,0, 18> translate<  .17,-.11,0> rotate<0,90,0> scale<1,1,1.3>}
 }  
  
difference{superellipsoid{<.01,1> rotate<90,0,0> scale <.70,.12,.49> translate<0,.32,0>}  
box{<-2,2,-2>,<2,.361,2>} box{<-2,-2,-2>,<2,.315,2>} } 

difference{superellipsoid{<.01,1> rotate<90,0,0> scale <.70*1.1,.12,.49*1.1> translate<0,.32,0>}  
box{<-2,2,-2>,<2,.361,2>} box{<-2,-2,-2>,<2,.315,2>} translate <0,-.27,0>} 

box{<-.75,.05,-.41>,<.75,.1,.41> rotate<0,0, 40> translate<0,1.8,0>}
box{<-.75,.05,-.41>,<.75,.1,.41> rotate<0,0,-40> translate<0,1.8,0>}
 difference{box{<-.6,1.9,-.4>,<.6,1,.4>} box{<-.5,.5,-.3>,<.5,2,.3>} 
 cylinder{<0,1,-1>,<0,1,0>,.5} cylinder{<-1,1,0>,<1,1,0>,.3} } 
 difference{torus{.5,.015 rotate<90,0,0> } box{<-3,-3,-3>,<3,0,3>}translate<0,1,-.4>}
 difference{torus{.3,.015 rotate<0,0,90> } box{<-3,-3,-3>,<3,0,3>}translate<-.6,1,0>} 
 difference{torus{.3,.015 rotate<0,0,90> } box{<-3,-3,-3>,<3,0,3>}translate< .6,1,0>} 
torus{.37,.03 scale<1,.5,1> rotate<90,0,0> translate<0,.9,-.295>} 
torus{.14,.03 scale<1,.5,1> rotate<90,0,0> translate<0,.9,-.295>}
torus{.09,.03 scale<1,.5,1> rotate<90,0,0> translate<0,.9,-.295>} 
torus{.04,.03 scale<1,.5,1> rotate<90,0,0> translate<0,.9,-.295>}
}

#declare CClock2 = difference{object{CClock1  texture{CCWood}}
cylinder{<-.3,.47,-.4>,<-.3,.47,-.1>, .034  texture{CCWood} } cylinder{< .3,.47,-.4>,< .3,.47,-.1>, .034  texture{CCWood} }
union{ cylinder{<0,0,0>,<0,0,-.41>,.1 translate<0,1.66,0>}box{<-.1,0,0>,<.1,-.12,-.41> translate<0,1.66,0>} texture{CCWood}}
box{<-3,0,-3>,<3,3,3> rotate<0,0, 40> translate<0,1.9,0> texture{CCWood translate <0,2.5,0>}}
box{<-3,0,-3>,<3,3,3> rotate<0,0,-40> translate<0,1.9,0> texture{CCWood translate <0,1.3,0>}}
#declare cfc1 = 0; #while (cfc1<360) cone{<0,.16,0>,.03,<0,.01,0>,.01 scale <1,1,.5>  rotate <0,0,cfc1> translate<0,.9,-.316> texture{CCWood}} 
difference{sphere{<0,0,0>,.02} cylinder{<0,.021,-2>,<0,.021,2>,.021} scale<2.5,1.4,.5> translate <0,.38,0> rotate <0,0,cfc1> translate<0,.9,-.305>  texture{CCWood}}
#declare cfc1=cfc1+15; #end
} 
 
#declare CCClmn = union{box{<-.07,1,-.07>,<.07,.97,.07>} cylinder{<0,.99,0>,<0,.4,0>,.039}box{<-.07,.4,-.07>,<.07,.36,.07>}
sphere{<0,0,0>,.06 scale<1,.5,1> translate<0,.685,0>}sphere{<0,0,0>,.06 scale<.8,.5,.8> translate<0,.635,0>}
sphere{<0,0,0>,.06 scale<.8,.5,.8> translate<0,.735,0>}sphere{<0,0,0>,.06 scale<1.15,.5,1.15> translate<0,.95,0>}
sphere{<0,0,0>,.06 scale<1,.5,1> translate<0,.90,0>}sphere{<0,0,0>,.06 scale<.8,.5,.8> translate<0,.85,0>}
sphere{<0,0,0>,.06 scale<1.15,.5,1.15> translate<0,.42,0>}sphere{<0,0,0>,.06 scale<1,.5,1> translate<0,.47,0>}
sphere{<0,0,0>,.06 scale<.8,.5,.8> translate<0,.52,0>} texture{CCWood}}

#declare HrH1 = union{ cylinder{<0,0,0>,<0,0,-.02>,.05 }
difference{box{<-.05,-.05,0>,<.05,.05,-.02> rotate <0,0,45>} box{<-1,0,-1>,<1,-1,1>} scale <.8,2.7,1> translate<0,.01,0>}
}
#declare HrH = difference{object{HrH1} cylinder{<0,0,-1>,<0,0,1>,.03} cylinder{<0,0,-1>,<0,0,1>,.012 scale <.9,2.5,1> translate<0,.11,0>}
 cylinder{<0,0,-1>,<0,0,1>,.012 scale <.9,2.5,1> translate<0,.03,0>}
 cylinder{<0,0,-1>,<0,0,1>,.05 translate <.07,.07,0>}  cylinder{<0,0,-1>,<0,0,1>,.05 translate <-.07,.07,0>}} 

#declare MnH1 = union{ cylinder{<0,0,0>,<0,0,-.02>,.05 }
difference{box{<-.05,-.05,0>,<.05,.05,-.02> rotate <0,0,45>} box{<-1,0,-1>,<1,-1,1>} scale <.6,4.5,1> translate<0,.01,0>}
}
#declare MnH = difference{object{MnH1} cylinder{<0,0,-1>,<0,0,1>,.03} cylinder{<0,0,-1>,<0,0,1>,.012 scale <.9,3.8,1> translate<0,.15,0>}
 cylinder{<0,0,-1>,<0,0,1>,.012 scale <.9,2.9,1> translate<0,.04,0>}
 cylinder{<0,0,-1>,<0,0,1>,.05 translate <.07,.08,0>}  cylinder{<0,0,-1>,<0,0,1>,.05 translate <-.07,.08,0>}} 

#declare CkBrd1 = difference{sphere{<0,0,0>,.05 scale <.7,1,1> } 
sphere{<-.06,-.02,0>,.05 scale <.6,1,1> } sphere{< .06,-.02,0>,.05 scale <.6,1,1> } 
texture{CCBlu} } 

#declare CkBrd2 = union{object{CkBrd1}  difference{cone{<0,0,0>,.02,<0,0,-.135>,.002} sphere{<0,0,0>,.03} rotate <-30,0,0> texture{CCBlu}}
sphere{<0,0,0>,.025 texture{CCBlu} }
rotate <0,-45,0> }

#declare CkBrd =   union{object{CkBrd2}  sphere{<0,0,0>,.06 scale<1,1,1.5> rotate <15,0,0> translate<0,-.07,.10> texture{CCBlu} }  
translate <0,1.7,-.41> } 

#declare CClock3 = union{object{CClock2} object{CCClmn translate<-.55,0,-.35>}  object{CCClmn translate< .55,0,-.35>} 
object{CCClmn translate<-.55,0, .35>}  object{CCClmn translate< .55,0, .35>}
text { ttf "coprgtb.ttf" "XII" .8, 0 scale <.06,.18,.2> translate<-.041,1.095,-.305> texture{MGld}}
text { ttf "coprgtb.ttf" "XI" .8, 0 scale <.06,.18,.2> translate<-.034,1.095-.9,-.305> rotate<0,0,30*1> translate<0,.9,0> texture{MGld}}
text { ttf "coprgtb.ttf" "X" .8, 0 scale <.06,.18,.2> translate<-.018,1.095-.9,-.305> rotate<0,0,30*2> translate<0,.9,0> texture{MGld}} 
text { ttf "coprgtb.ttf" "IX" .8, 0 scale <.06,.18,.2> translate<-.034,1.095-.9,-.305> rotate<0,0,30*3-2> translate<0,.9,0> texture{MGld}}
text { ttf "coprgtb.ttf" "VIII" .8, 0 scale <.06,.18,.2> translate<-.050,1.095-.9,-.305> rotate<0,0,30*4> translate<0,.9,0> texture{MGld}}
text { ttf "coprgtb.ttf" "VII" .8, 0 scale <.06,.18,.2> translate<-.041,1.095-.9,-.305> rotate<0,0,30*5> translate<0,.9,0> texture{MGld}}
text { ttf "coprgtb.ttf" "VI" .8, 0 scale <.06,.18,.2> translate<-.034,1.095-.9,-.305> rotate<0,0,30*6> translate<0,.9,0> texture{MGld}}
text { ttf "coprgtb.ttf" "V" .8, 0 scale <.06,.18,.2> translate<-.018,1.095-.9,-.305> rotate<0,0,30*7> translate<0,.9,0> texture{MGld}}
text { ttf "coprgtb.ttf" "IIII" .8, 0 scale <.06,.18,.2> translate<-.034,1.095-.9,-.305> rotate<0,0,30*8> translate<0,.9,0> texture{MGld}} 
text { ttf "coprgtb.ttf" "III" .8, 0 scale <.06,.18,.2> translate<-.018,1.095-.9,-.305> rotate<0,0,30*9> translate<0,.9,0> texture{MGld}}
text { ttf "coprgtb.ttf" "II" .8, 0 scale <.06,.18,.2> translate<-.018,1.095-.9,-.305> rotate<0,0,30*10> translate<0,.9,0> texture{MGld}} 
text { ttf "coprgtb.ttf" "I" .8, 0 scale <.06,.18,.2> translate<-.005,1.095-.9,-.305> rotate<0,0,30*11> translate<0,.91,0> texture{MGld}}
union{ cylinder{<0,0,-.4>,<0,0,-.42>,.1 translate<0,1.66,0>}box{<-.1,0,-.4>,<.1,-.11,-.42> translate<0,1.66,0>} 
  texture{CCWood translate<0,-.2,0>} translate<-.1,0,.4> rotate <0,-130,0> translate<.1,0,-.4>} 
difference{torus{.1,.01} box{<-1,-1,0>,<1,1,-1>} rotate <-90,0,0> translate<0,1.66,-.4> texture{CCWood}}
cylinder{<-.1,0,-.4>,<-.1,-.12,-.4>,.015 translate<0,1.66,0>texture{CCWood}}
cylinder{< .1,0,-.4>,< .1,-.12,-.4>,.015 translate<0,1.66,0>texture{MDMt}} 
box{<-.11,-.13,-.4>,<.11,-.11,-.42> translate<0,1.66,0> texture{CCWood}}
difference{box{<-.05,-.080,0>,<.05,-.11,-.42>} box{<-.03,0,0>,<.03,-.095,-.45>}translate<0,1.66,0> texture{MDMt}}  
object{HrH texture{BWht} rotate<0,0,150> translate <0,.9,-.29>} 
object{MnH texture{BWht}rotate<0,0,0> translate <0,.9,-.30>}
sphere{<0,0,0>,.035 texture{MGld} scale<1,1,.3> translate <0,.9,-.32>} sphere{<0,0,0>,.035 texture{MGld} scale<.5,.5,.2> translate <0,.9,-.33>} 
object{CkBrd translate <0,0,-.03>} 
torus{.035,.01 rotate<90,0,0> translate<-.3,.47,-.3>texture{CCWood}} 
torus{.035,.01 rotate<90,0,0> translate< .3,.47,-.3>texture{CCWood}} 
cylinder{<-.3,.47,-.29>,<-.3,.47,-.1>, .012  texture{MDMt} } cylinder{< .3,.47,-.29>,< .3,.47,-.1>, .012  texture{MDMt} }
}
 
object{CClock3  scale 1.1 rotate<0,-20,0> translate<1.1,.11,1.1>} 

//Airplane Clock
//======================================================================================================
#declare FRng1 = difference{cylinder{<0,0,0>,<0,0, .06>, .24} cylinder{<0,0,.2>,<0,0,-.2>, .20}  }  
#declare FRng = union{ object{FRng1} 
torus{.22,.02 scale<1,1,1> rotate <90,0,0>} texture {MChr}}
 
#declare PlCk1 = union{object {FRng translate<0,0,-.5>}   
difference{sphere{<0,0,0>,.205} sphere{<0,0,0>,.202}scale <1,1,.15> translate <0,0,-.52>material {Crys} }
cylinder{<0,0,-.44>,<0,0, 0>, .24 texture{MChr}} 
intersection{cylinder{<0,0, .8>,<0,0, 0>, .24}  sphere{<0,.24,0>,.485 scale<.8,1,1.6>}texture{MChr}}
cylinder {<0,0,0>,<0,-.89,0>, .025 texture {MChr}}
intersection{sphere{<0,0,0>,.26} cylinder{<0,0,0>,<0,1,0>.24} scale <2,.5,1> translate <0,-.9,0>texture {MChr}}  
cone{<0,.02,0>,.12,<0,.30,0>,.09 translate <0,-.9,0> texture {MChr}} 
intersection{ sphere{<0,0,0>,.25 scale<4,.3,1>}  sphere{<0,0,.02>,.25 scale<4,.6,1>} texture{MChr}} 
#declare Stblz = intersection{ sphere{<0,0,0>,.25 scale<4,.3,1>}  sphere{<0,0,.02>,.25 scale<4,.6,1>}
scale <.4,.4,.4>  texture{MChr}}
object{Stblz  rotate <0,0,0> translate<0,.18,.6>} difference{object{Stblz} box{<-1,-1,-1>,<0,1,1>} rotate <0,0,90> 
rotate <10,0,0> translate<0,.06,.65>}          
intersection{cone{<0,0,0>,.12,<0,0,.40>,.04} sphere{<0,0,.23>,.24 scale <.9,.9,1.2>}  translate <.55,0,-.235> texture{MChr}} 
sphere{<0,0,0>,.04 scale <1,1,2>  translate <.55,0,-.255> texture{MChr}}
sphere{<0,0,0>,.04 scale <.4,3,1> rotate <0,45,0> translate<0,.09,0> rotate <0,0,35> translate <.55,0,-.26> texture{MChr}}
sphere{<0,0,0>,.04 scale <.4,3,1> rotate <0,45,0> translate<0,.09,0> rotate <0,0,155> translate <.55,0,-.26> texture{MChr}}
sphere{<0,0,0>,.04 scale <.4,3,1> rotate <0,45,0> translate<0,.09,0> rotate <0,0,275> translate <.55,0,-.26> texture{MChr}}
intersection{cone{<0,0,0>,.12,<0,0,.40>,.04} sphere{<0,0,.23>,.24 scale <.9,.9,1.2>}  translate <-.55,0,-.235> texture{MChr}} 
sphere{<0,0,0>,.04 scale <.4,3,1> rotate <0,45,0> translate<0,.09,0> rotate <0,0,65> translate <-.55,0,-.26> texture{MChr}}
sphere{<0,0,0>,.04 scale <.4,3,1> rotate <0,45,0> translate<0,.09,0> rotate <0,0,185> translate <-.55,0,-.26> texture{MChr}}
sphere{<0,0,0>,.04 scale <.4,3,1> rotate <0,45,0> translate<0,.09,0> rotate <0,0,305> translate <-.55,0,-.26> texture{MChr}} 
sphere{<0,0,0>,.04 scale <1,1,2>  translate <-.55,0,-.255> texture{MChr}} 
text { ttf "kino.ttf" "12" .8, 0 scale <.12,.12,.2> translate<-.03,.11,-.45> texture{BWhtB}}
text { ttf "kino.ttf" "6" .8, 0 scale <.12,.12,.2> translate<-.02,-.19,-.45> texture{BWhtB}}
text { ttf "kino.ttf" "9" .8, 0 scale <.12,.12,.2> translate<-.18,-.04,-.45> texture{BWhtB}}
text { ttf "kino.ttf" "3" .8, 0 scale <.12,.12,.2> translate< .14,-.04,-.45> texture{BWhtB}} 
box{<-.005,.19,.1>,<.005,.14,-.445>texture{BWhtB} rotate <0,0,30>}   box{<-.005,.19,.1>,<.005,.14,-.445>texture{BWhtB} rotate <0,0,60>} 
box{<-.005,.19,.1>,<.005,.14,-.445>texture{BWhtB} rotate <0,0,120>}  box{<-.005,.19,.1>,<.005,.14,-.445>texture{BWhtB} rotate <0,0,150>}
box{<-.005,.19,.1>,<.005,.14,-.445>texture{BWhtB} rotate <0,0,210>}  box{<-.005,.19,.1>,<.005,.14,-.445>texture{BWhtB} rotate <0,0,240>}
box{<-.005,.19,.1>,<.005,.14,-.445>texture{BWhtB} rotate <0,0,300>}  box{<-.005,.19,.1>,<.005,.14,-.445>texture{BWhtB} rotate <0,0,330>} 
cylinder {<0,0,0>,<0,0,-.465>,.035 texture{BWhtB} } cone{<0,0,0>,.034,<0,.12,0 >,.002 scale <1,1,.1> 
translate <0,0,-.465> rotate <0,0,150> texture{BWhtB} } 
cylinder {<0,0,0>,<0,0,-.475>,.025 texture{BWhtB} } cone{<0,0,0>,.024,<0,.18,0 >,.002 scale <1,1,.1> 
translate <0,0,-.470> rotate <0,0,0> texture{BWhtB} } 
cylinder {<0,0,0>,<0,0,-.485>,.015 texture{BWhtB} } cone{<0,-.03,0>,.010,<0,.18,0 >,.002 scale <1,1,.1> 
translate <0,0,-.480> rotate <0,0,315> texture{BWhtB} } 
} 

#declare PlCk = difference{object{PlCk1} torus{.24,.008 rotate<90,0,0> translate <0,0,-.42>texture{MChr} }  }
object{PlCk rotate <0,25,0> translate <2.8,.9,1>}